Arduino GPS – GPS Tracker to SD Card (Adafruit Ultimate GPS)

Eli the Computer Guy *NEW, Arduino GPS

This project shows you how to create a tracking device that logs location and speed of the device to an SD card, and also displays the infromation to an LCD Screen.

Notes:

  • We use an Arduino Uno with WiFi Rev 2 because when using an Arduino Uno board I was receiving readings that were massive loff for Latitude.
  • We use an Arduino Ethernet Shield because the Arduino Uno with WiFi needs an SD Shield that has ICSP Headers.

Prerequisite Classes:

Libraries:

Functional Parts in the Project:

//This is a modification of the Example code: GPS_SoftwareSerial_Parsing
//Works well with an Arduino Uno with WiFi Rev2,
//with Arduino Uno I get massive Latitude Issues
//Uses Official Ethernet Shield for ICSP Headers required for SD Usage on Arduino Uno with WiFi

#include <Adafruit_GPS.h>
#include <SoftwareSerial.h>

//ETCG Notes - LCD I2C Screen
#include <Wire.h>
#include <LCD.h>
#include <LiquidCrystal_I2C.h>

LiquidCrystal_I2C lcd(0x27, 2, 1, 0, 4, 5, 6, 7);

//ETCG Notes -- SD Card Setup on Ethernet Shield
#include <SPI.h>
#include <SD.h>
#define sdPin 4
File logFile;

// Connect the GPS Power pin to 5V
// Connect the GPS Ground pin to ground
// Connect the GPS TX (transmit) pin to Digital 8
// Connect the GPS RX (receive) pin to Digital 7

// you can change the pin numbers to match your wiring:
SoftwareSerial mySerial(8, 7);
Adafruit_GPS GPS(&mySerial);

// Set GPSECHO to 'false' to turn off echoing the GPS data to the Serial console
// Set to 'true' if you want to debug and listen to the raw GPS sentences
#define GPSECHO  true

void setup()
{

  //ETCG Notes - Start LCD
  lcd.begin(20, 4);
  lcd.setBacklightPin(3, POSITIVE);
  lcd.setBacklight(HIGH);
  lcd.setCursor(0, 0);
  lcd.print("Arduino GPS");

  //ETCG Comment -- Checks for SD Card, if not found keeps loading.
  //Use WHILE loop below to require SD Card
  if (!SD.begin(sdPin)) {
    lcd.setCursor(0, 1);
    lcd.print("SD Card Not Found");
    delay(2000);
  }

  //ETCG Notes -- Uncomment While Loop if You REQUIRE SD Card
  /*
     while (!SD.begin(sdPin)) {
    lcd.setCursor(0, 1);
    lcd.print("SD Card Not Found");
    }
  */

  // connect at 115200 so we can read the GPS fast enough and echo without dropping chars
  // also spit it out
  Serial.begin(115200);
  delay(5000);
  Serial.println("Adafruit GPS library basic test!");

  // 9600 NMEA is the default baud rate for Adafruit MTK GPS's- some use 4800
  GPS.begin(9600);

  // uncomment this line to turn on RMC (recommended minimum) and GGA (fix data) including altitude
  GPS.sendCommand(PMTK_SET_NMEA_OUTPUT_RMCGGA);
  // uncomment this line to turn on only the "minimum recommended" data
  //GPS.sendCommand(PMTK_SET_NMEA_OUTPUT_RMCONLY);
  // For parsing data, we don't suggest using anything but either RMC only or RMC+GGA since
  // the parser doesn't care about other sentences at this time

  // Set the update rate
  GPS.sendCommand(PMTK_SET_NMEA_UPDATE_1HZ);   // 1 Hz update rate
  // For the parsing code to work nicely and have time to sort thru the data, and
  // print it out we don't suggest using anything higher than 1 Hz

  // Request updates on antenna status, comment out to keep quiet
  GPS.sendCommand(PGCMD_ANTENNA);

  delay(1000);
  // Ask for firmware version
  mySerial.println(PMTK_Q_RELEASE);

}

uint32_t timer = millis();
void loop()                     // run over and over again
{
  char c = GPS.read();
  // if you want to debug, this is a good time to do it!
  if ((c) && (GPSECHO))
    Serial.write(c);

  // if a sentence is received, we can check the checksum, parse it...
  if (GPS.newNMEAreceived()) {
    // a tricky thing here is if we print the NMEA sentence, or data
    // we end up not listening and catching other sentences!
    // so be very wary if using OUTPUT_ALLDATA and trytng to print out data
    //Serial.println(GPS.lastNMEA());   // this also sets the newNMEAreceived() flag to false

    if (!GPS.parse(GPS.lastNMEA()))   // this also sets the newNMEAreceived() flag to false
      return;  // we can fail to parse a sentence in which case we should just wait for another
  }

  // approximately every 2 seconds or so, print out the current stats
  if (millis() - timer > 2000) {
    timer = millis(); // reset the timer

    Serial.print("\nTime: ");
    if (GPS.hour < 10) {
      Serial.print('0');
    }
    Serial.print(GPS.hour, DEC); Serial.print(':');
    if (GPS.minute < 10) {
      Serial.print('0');
    }
    Serial.print(GPS.minute, DEC); Serial.print(':');
    if (GPS.seconds < 10) {
      Serial.print('0');
    }
    Serial.print(GPS.seconds, DEC); Serial.print('.');
    if (GPS.milliseconds < 10) {
      Serial.print("00");
    } else if (GPS.milliseconds > 9 && GPS.milliseconds < 100) {
      Serial.print("0");
    }

    Serial.println(GPS.milliseconds);
    Serial.print("Date: ");
    Serial.print(GPS.day, DEC); Serial.print('/');
    Serial.print(GPS.month, DEC); Serial.print("/20");
    Serial.println(GPS.year, DEC);
    Serial.print("Fix: "); Serial.print((int)GPS.fix);
    Serial.print(" quality: "); Serial.println((int)GPS.fixquality);
    if (GPS.fix) {
      Serial.print("Location: ");
      Serial.print(GPS.latitude, 8); Serial.print(GPS.lat);
      Serial.print(", ");
      Serial.print(GPS.longitude, 8); Serial.println(GPS.lon);
      //ETCG Notes -- The Following Gives Coordinates in formant you can plug into
      //Google Maps (Degrees)
      Serial.println("Location in Degrees");
      Serial.print(GPS.latitudeDegrees, 8);
      Serial.print(", ");
      Serial.println(GPS.longitudeDegrees, 8);

      Serial.print("Speed (knots): "); Serial.println(GPS.speed);
      Serial.print("Angle: "); Serial.println(GPS.angle);
      Serial.print("Altitude: "); Serial.println(GPS.altitude);
      Serial.print("Satellites: "); Serial.println((int)GPS.satellites);

      //ETCG Notes -- Print to LCD Screen
      lcd.clear();
      lcd.setCursor(0, 1);
      lcd.print("Spd: ");
      lcd.setCursor(5, 1);
      float mph;
      mph = (GPS.speed) * 1.15;
      lcd.print(mph);
      lcd.setCursor(0, 2);
      lcd.print("Lat: ");
      lcd.setCursor(5, 2);
      lcd.print(GPS.latitudeDegrees, 8);
      lcd.setCursor(0, 3);
      lcd.print("Lon: ");
      lcd.setCursor(5, 3);
      lcd.print(GPS.longitudeDegrees, 8);

      //ETCG Notes -- Write to SD Card
      logFile = SD.open("gpsLog.txt", FILE_WRITE);


      String timeStamp = String(GPS.day, DEC) + (",") + String(GPS.month, DEC) + (",") + String(GPS.year, DEC) + (" - ")
                         + String(GPS.hour, DEC) + (":") + String(GPS.minute, DEC) + (":") + String(GPS.seconds, DEC);

      if (logFile) {
        logFile.print("Time Stamp: ");
        logFile.print(timeStamp);
        logFile.print(" Speed: ");
        logFile.print(mph);
        logFile.print(" Lat/long:  ");
        logFile.print(GPS.latitudeDegrees, 8);
        logFile.print(", ");
        logFile.println(GPS.longitudeDegrees, 8);
        logFile.close();

        lcd.setCursor(17, 0);
        lcd.print("SD+");
      } else {
        lcd.setCursor(17, 0);
        lcd.print("   ");
        lcd.setCursor(17, 0);
        lcd.print("SD-");
      }

    } else {
      lcd.clear();
      lcd.setCursor(0, 1);
      lcd.print("No Signal");
    }
    lcd.setCursor(0, 0);
    lcd.print("Satellites: ");
    lcd.setCursor(12, 0);
    lcd.print((int)GPS.satellites);
  }
}

Related Articles

Be the first to comment

Leave a Reply